/*Published: 12/31/2012*/

/**************************   COMMENTS   *******************************/
/* THIS INPUT STATMENT IS FOR THE 2012 SEER-MEDICARE LINKAGE.          */
/* IF YOU RECEIVED HHA FILES BEFORE DECEMBER 2012 THEN YOU WILL        */
/* NEED A DIFFERENT INPUT STATEMENT. PLEASE CONTACT IMS VIA E-MAIL AT  */
/* SEER-MEDICARE@IMSWEB.COM AND AN INPUT STATEMENT WILL BE SENT TO YOU */
/***********************************************************************/
/*                                                                     */
/* For cancer files, Patient Identifier is @01 REGCASE $char10.        */
/* For non-cancer files, Patient Identifier is @01 HICBIC $char11.     */
/*                                                                     */
/***********************************************************************/

/***************   IMPORTANT PROGRAMING NOTES   ************************/
/*               TO IDENTIFY CLAIMS PER PATIENT                        */
/*                                                                     */
/* The Patient ID, daily process date (column 387), and link number    */
/* (column 377) should be used to identify all the records for each    */
/* claim per patient.  All are needed to identify a claim.             */
/***********************************************************************/

/***********************************************************************/
/*                   TO CALCULATE COSTS PER PATIENT                    */
/*                                                                     */
/* When calculating costs per patient you will need to use the claim   */
/* payment amount variable (column 65).  The value from the record     */
/* count (column 399) equal to 1 should be used.  This will eliminate  */
/* duplicate counting from other records.                              */
/***********************************************************************/

/***********************************************************************/
/* If you are using PC SAS to read in these files you will have to     */
/* un-zip the files first and use the un-zipped filename statement,    */
/* rather than using the zipped files and statement.                   */
/***********************************************************************/

*filename hhafixed '/directory/hhasaf10.txt';                    /* reading in an un-zipped file* /
*filename hhafixed pipe 'gunzip -c /directory/hhasaf10.txt.gz';  /* reading in a zipped file */
*filename hhafixed pipe 'gunzip -c /directory/hhasaf*.txt.gz';   /* using wildcard to match multiple files */

options nocenter validvarname=upcase;

data hha;
  infile hhafixed lrecl=658 missover pad;
  input 
    @001  patient_id $char11. /* Patient ID (for either Cancer or Non-Cancer Patients) */
    /*@001  REGCASE    $char10.*/ /*ID for Cancer Patients*/
    /*@001  HICBIC     $char11.*/ /*ID for Non Cancer Patients*/
    @012  bic        $char2.
    @014  state_cd   $char2.
    @016  cnty_cd    $char3.
    @019  bene_zip   $char9.  /****************Special Permission Required***************/
    @028  ms_cd      $char2.
    @030  clm_type   $char2.
    @032  from_dtm   $char2.
    @034  from_dtd   $char2.
    @036  from_dty   $char4.
    @040  thru_dtm   $char2.
    @042  thru_dtd   $char2.
    @044  thru_dty   $char4.
    @048  fi_num     $char5.
    @053  provider   $char6.
    @059  query_cd   $char1.
    @060  fac_type   $char1.
    @061  typesrvc   $char1.
    @062  freq_cd    $char1.
    @063  nopay_cd   $char2.  /* $char1. in 2010 Linkage */
    @065  pmt_amt    15.2
    @080  tot_chrg   15.2
    @095  prpay_cd   $char1.
    @096  prpayamt   15.2
    @111  actioncd   $char1.
    @112  prvstate   $char2.
    @114  orgnpinm   $char10.
    @124  at_upin    $char6.
    @130  at_npi     $char10.
    @140  op_upin    $char6.
    @146  op_npi     $char10.
    @156  ot_upin    $char6.
    @162  ot_npi     $char10.
    @172  stus_cd    $char2.
    @174  pps_ind    $char1.
    @175  tot_line   $char3.  /* new in 2012 Linkage */
    @178  seg_line   $char2.  /* new in 2012 Linkage */
    @180  authrztn   $char18. /* new in 2012 Linkage */
    @198  prcrrtrn   $char2.  /* new in 2012 Linkage */
    @200  srvcfac    $char9.  /* new in 2012 Linkage */
    @209  hhdgncnt   $char2.  /* new in 2012 Linkage */
    @211  hhconcnt   $char2.  /* new in 2012 Linkage */
    @213  hhrevcnt   $char2.  /* $char3. in 2010 Linkage */
    @215  lupaind    $char1.  /* new in 2012 Linkage */
    @216  hha_rfrl   $char1.  /* new in 2012 Linkage */
    @217  dsch_dty   $char4.  /* new in 2012 Linkage */
    @221  dsch_dtm   $char2.  /* new in 2012 Linkage */
    @223  dsch_dtd   $char2.  /* new in 2012 Linkage */
    @225  center     $char4.
    @229  cendm      $char2.  /* named CEN_DTM in 2010 Linkage */
    @231  cendd      $char2.  /* named CEN_DTD in 2010 Linkage */
    @233  cendy      $char4.  /* named CEN_DTY in 2010 Linkage */
    @237  revan1     $char5.  /* new in 2012 Linkage */
    @242  revhipps   $char5.  /* new in 2012 Linkage */
    @247  hcpcs      $char5.
    @252  mf1        $char2.
    @254  mf2        $char2.
    @256  unit       8.
    @264  rate       15.2
    @279  rev_msp1   15.2     /* new in 2012 Linkage */
    @294  rev_msp2   15.2     /* new in 2012 Linkage */
    @309  rprvdpmt   15.2     /* new in 2012 Linkage */
    @324  charge     15.2
    @339  pay        15.2
    @354  revncvr    15.2     /* new in 2012 Linkage */
    @369  ded        $char1.
    @370  rstusind   $char2.  /* new in 2012 Linkage */
    @372  dup_chk    $char1.  /* new in 2012 Linkage */
    @373  year       $char4.
    @377  link_num   $char10. /* use daily date and link number to identify a claim for each patient */
    @387  daily_dtm  $char2.  /* use daily date and link number to identify a claim for each patient */
    @389  daily_dtd  $char2.
    @391  daily_dty  $char4.
    @395  tot_seg    $char2.
    @397  seg_num    $char2.
    @399  rec_count  $char3.
    @402  visitcnt   $char4.
    @406  hhastdym   $char2.
    @408  hhastdyd   $char2.
    @410  hhastdty   $char4.
    @414  ric_cd     $char1.
    @;

  array mcoind(2)  $ mcoind1 -mcoind2;
  array mconum(2)  $ mconum1 -mconum2;
  array mcoptn(2)  $ mcoptn1 -mcoptn2;
  array mcoedty(2) $ mcoedty1-mcoedty2;
  array mcoedtm(2) $ mcoedtm1-mcoedtm2;
  array mcoedtd(2) $ mcoedtd1-mcoedtd2;
  array mcotdty(2) $ mcotdty1-mcotdty2;
  array mcotdtm(2) $ mcotdtm1-mcotdtm2;
  array mcotdtd(2) $ mcotdtd1-mcotdtd2;
  inc = 415;
  do j = 1 to 2;
    input 
      @inc+0   mcoind(j)   $char1.  /* new in 2012 Linkage */
      @inc+1   mconum(j)   $char5.  /* new in 2012 Linkage */
      @inc+6   mcoptn(j)   $char1.  /* new in 2012 Linkage */
      @inc+7   mcoedty(j)  $char4.  /* new in 2012 Linkage */
      @inc+11  mcoedtm(j)  $char2.  /* new in 2012 Linkage */
      @inc+13  mcoedtd(j)  $char2.  /* new in 2012 Linkage */
      @inc+15  mcotdty(j)  $char4.  /* new in 2012 Linkage */
      @inc+19  mcotdtm(j)  $char2.  /* new in 2012 Linkage */
      @inc+21  mcotdtd(j)  $char2.  /* new in 2012 Linkage */
      @;
    inc=inc+23;
  end;
  
  input
    @461 (dgn_cd1-dgn_cd25) ($char7.)  /* $char5. and only 10 codes in 2010 Linkage */
    @;

  array ocrncind(2) $ ocrncind1 - ocrncind2;
  array ocrnc_cd(2) $ ocrnc_cd1 - ocrnc_cd2;
  array ocrncdty(2) $ ocrncdty1 - ocrncdty2;
  array ocrncdtm(2) $ ocrncdtm1 - ocrncdtm2;
  array ocrncdtd(2) $ ocrncdtd1 - ocrncdtd2;
  inc = 636;
  do j = 1 to 2;
    input 
      @inc+0  ocrncind(j)  $char1.  /* new in 2012 Linkage */
      @inc+1  ocrnc_cd(j)  $char2.  /* new in 2012 Linkage */
      @inc+3  ocrncdty(j)  $char4.  /* new in 2012 Linkage */
      @inc+7  ocrncdtm(j)  $char2.  /* new in 2012 Linkage */
      @inc+9  ocrncdtd(j)  $char2.  /* new in 2012 Linkage */
      @;
    inc=inc+11;
  end;
  
  input;

  drop j inc;

  label
    patient_id = 'Patient ID'
    /* regcase  = 'SEER Registry Case Number - Cancer Patients' */
    /* hicbic   = 'Patient ID for the Non Cancer Patients' */
    bic        = '12 - BIC'
    state_cd   = '14 - State code'
    cnty_cd    = '42 - County code'
    bene_zip   = '49 - Zip code (Special Permission Required)'
    ms_cd      = '53 - Medicare Status code'
    clm_type   = '7 - NCH Claim Type Code'
    from_dtm   = '15 - Month of Claim From date'
    from_dtd   = '15 - Day of Claim From date'
    from_dty   = '15 - Year of Claim From date'
    thru_dtm   = '16 - Month of Claim Thru date'
    thru_dtd   = '16 - Day of Claim Thru date'
    thru_dty   = '16 - Year of Claim Thru date'
    fi_num     = '46 - Ficarr ID number'
    provider   = '23 - Provider number'
    query_cd   = '22 - Claim query code'
    fac_type   = '34 - Claim facility type'
    typesrvc   = '35 - Classification type code'
    freq_cd    = '36 - Claim frequency code'
    nopay_cd   = '62 - Claim Medicare Non Payment Reason Code'
    pmt_amt    = '64 - Claim payment amount'
    tot_chrg   = '103 - Claim total charge amount'
    prpay_cd   = '66 - Primary payer code'
    prpayamt   = '65 - Primary payer payment amount'
    actioncd   = '68 - FI Claim action code'
    prvstate   = '70 - NCH Provider State Code'
    orgnpinm   = '71 - Organization NPI Number'
    at_upin    = '73 - Claim Attending Physician UPIN'
    at_npi     = '74 - Claim Attending Physician NPI'
    op_upin    = '79 - Claim Operating Physician UPIN'
    op_npi     = '80 - Claim Operating Physician NPI'
    ot_upin    = '85 - Claim Other Physician UPIN'
    ot_npi     = '86 - Claim Other Physician NPI'
    stus_cd    = '98 - Patient discharge status code'
    pps_ind    = '102 - Claim PPS Indicator Code'
    tot_line   = '28 - Claim Total Line Count'
    seg_line   = '29 - Claim Segment Line Count'
    authrztn   = '93 - Claim Treatment Authorization Number'
    prcrrtrn   = '104 - Claim Pricer Return Code'
    srvcfac    = '108 - Claim Service Facility Zip Code'
    hhdgncnt   = '116 - Claim diagnosis code count'
    hhconcnt   = '119 - Claim related condition code count'
    hhrevcnt   = '123 - Claim Total Line count' /* Revenue Center Code Count */
    lupaind    = '126 - HHA low utilization payment adjustment'
    hha_rfrl   = '127 - HHA referral code'
    dsch_dty   = '131 - NCH Beneficiary discharge year'
    dsch_dtm   = '131 - NCH Beneficiary discharge month'
    dsch_dtd   = '131 - NCH Beneficiary discharge day'
    center     = '179 - Revenue Center Code'
    cendm      = '180 - Revenue Center Month'
    cendd      = '180 - Revenue Center Day'
    cendy      = '180 - Revenue Center Year'
    revan1     = '181 - Revenue Center 1st ANSI Code'
    revhipps   = '185 - Revenue Center APC/HIPPS'
    hcpcs      = '186 - HCPCS Code'
    mf1        = '187 - Initial modifier code'
    mf2        = '188 - Second modifier code'
    unit       = '200 - Revenue Center unit count'
    rate       = '201 - Revenue Center rate amount'
    rev_msp1   = '206 - 1st Medicare Secondary Payer Paid Amount'
    rev_msp2   = '207 - 2nd Medicare Secondary Payer Paid Amount'
    rprvdpmt   = '208 - Revenue Center Provider Payment Amount'
    charge     = '212 - Revenue Center total amount'
    pay        = '211 - Revenue Center Payment Amount'
    revncvr    = '213 - Non-Covered Charge Amount'
    ded        = '214 - Deductible coinsurance code'
    rstusind   = '216 - Revenue Center Status Indicator Code'
    dup_chk    = '217 - Duplicate Claim Check Indicator Code'
    year       = 'Claim Year'
    link_num   = '25 - Segment Link Number'
    daily_dtm  = '24 - Month of Daily claim processing'
    daily_dtd  = '24 - Day of Daily claim processing'
    daily_dty  = '24 - Year of Daily claim processing'
    tot_seg    = '26 - Claim Total Segment Count'
    seg_num    = '27 - Claim Segment Number'
    rec_count  = 'Claim record number'
    visitcnt   = '128 - Claim HHA Total Visit Count'
    hhastdym   = '132 - Claim HHA Care Start Month'
    hhastdyd   = '132 - Claim HHA Care Start Day'
    hhastdty   = '132 - Claim HHA Care Start Year'
    ric_cd     = '5 - NCH Near Line Record Identification Code'
    mcoind1    = '154 - MCO Trailer Indicator Code 1'
    mcoind2    = '154 - MCO Trailer Indicator Code 2'
    mconum1    = '144 - MCO Contract Number 1'
    mconum2    = '144 - MCO Contract Number 2'
    mcoptn1    = '145 - MCO Option Code 1'
    mcoptn2    = '145 - MCO Option Code 2'
    mcoedty1   = '146 - MCO Period Effective Year 1'
    mcoedtm1   = '146 - MCO Period Effective Month 1'
    mcoedtd1   = '146 - MCO Period Effective Day 1'
    mcoedty2   = '146 - MCO Period Effective Year 2'
    mcoedtm2   = '146 - MCO Period Effective Month 2'
    mcoedtd2   = '146 - MCO Period Effective Day 2'
    mcotdty1   = '147 - MCO Period Termination Year 1'
    mcotdtm1   = '147 - MCO Period Termination Month 1'
    mcotdtd1   = '147 - MCO Period Termination Day 1'
    mcotdty2   = '147 - MCO Period Termination Year 2'
    mcotdtm2   = '147 - MCO Period Termination Month 2'
    mcotdtd2   = '147 - MCO Period Termination Day 2'
    dgn_cd1    = '156 - ICD-9-CM code #1'
    dgn_cd2    = '156 - ICD-9-CM code #2'
    dgn_cd3    = '156 - ICD-9-CM code #3'
    dgn_cd4    = '156 - ICD-9-CM code #4'
    dgn_cd5    = '156 - ICD-9-CM code #5'
    dgn_cd6    = '156 - ICD-9-CM code #6'
    dgn_cd7    = '156 - ICD-9-CM code #7'
    dgn_cd8    = '156 - ICD-9-CM code #8'
    dgn_cd9    = '156 - ICD-9-CM code #9'
    dgn_cd10   = '156 - ICD-9-CM code #10'
    dgn_cd11   = '156 - ICD-9-CM code #11'
    dgn_cd12   = '156 - ICD-9-CM code #12'
    dgn_cd13   = '156 - ICD-9-CM code #13'
    dgn_cd14   = '156 - ICD-9-CM code #14'
    dgn_cd15   = '156 - ICD-9-CM code #15'
    dgn_cd16   = '156 - ICD-9-CM code #16'
    dgn_cd17   = '156 - ICD-9-CM code #17'
    dgn_cd18   = '156 - ICD-9-CM code #18'
    dgn_cd19   = '156 - ICD-9-CM code #19'
    dgn_cd20   = '156 - ICD-9-CM code #20'
    dgn_cd21   = '156 - ICD-9-CM code #21'
    dgn_cd22   = '156 - ICD-9-CM code #22'
    dgn_cd23   = '156 - ICD-9-CM code #23'
    dgn_cd24   = '156 - ICD-9-CM code #24'
    dgn_cd25   = '156 - ICD-9-CM code #25'
    ocrncind1  = '165 - NCH occurrence trailer indicator code 1'
    ocrncind2  = '165 - NCH occurrence trailer indicator code 2'
    ocrnc_cd1  = '166 - Claim related occurrence code 1'
    ocrnc_cd2  = '166 - Claim related occurrence code 2'
    ocrncdty1  = '167 - Claim related occurrence year 1'
    ocrncdtm1  = '167 - Claim related occurrence month 1'
    ocrncdtd1  = '167 - Claim related occurrence day 1'
    ocrncdty2  = '167 - Claim related occurrence year 2'
    ocrncdtm2  = '167 - Claim related occurrence month 2'
    ocrncdtd2  = '167 - Claim related occurrence day 2'
    ;
  
run;

proc contents data=hha position;
run;